One of the most prominent tools to simulate noise in circuits is the SPICE circuit simulator. The circuits can be as simple as a single resistor, as well as complex using many active devices and arbitrary real or analytic functions. In this work, we show how to do simulations on the equivalent circuit of an RF cavity using SPICE. Here one of the flavours of SPICE namely LTSpice [1]has been used mostly because of the convenient installation and waveform viewer, however other flavours can also be used accordingly such as the original SPICE from Berkeley [2] and NGSpice [3].
Introduction
According to Nyquist [4], the one-sided root mean square (RMS) of thermal noise voltage in units of $V/\sqrt{Hz}$ is given as \begin{equation} \sqrt{\bar{v_n^2}}=\sqrt{4k_BTR\Delta f} \end{equation} where the $k_B=1.3806488\ 10^{-23}$ J/K is the Boltzmann constant, R is the resistance in ohms, T is the temperature in Kelvin and $\Delta_f$ is the bandwidth in Hertz. The square of this value is the average noise power spectral density which shows the amount of power the signal carries in unit bandwidth.
In noise analysis, a noisy circuit is usually modelled as a noiseless circuit which is fed by a noise source. This way, one can define the so called input referred noise and the output referred noise which are connected via the gain $G$ of the circuit \begin{equation} v_{n,out}=G\ \ v_{n,in} \end{equation} The output referred noise seen on a node is the noise caused by the equivalent circuit where the independent voltage sources are short circuited and the independent current sources cut open. The input referred noise is then found by dividing the output referred noise by the gain.
As an example, let us begin with a resistor divider with the value of 100 ohms for each resistor. The equivalent circuit is the parallel circuit between $R_{int}$ and $R_1$ \begin{equation} R_{eq}=\dfrac{R_{int}\ R_1}{R_{int}+R_1}=50\ \Omega \end{equation} The output referred noise per unit bandwidth on the divider output is therefore is $\sqrt{4k_B\ 300\ 50}=910pV/Hz^{-1/2}$. The gain of the circuit on the voltage divider output is of course 0.5 \begin{equation} G=\dfrac{R_1}{R_{int}+R_1}=0.5 \end{equation} leading to an input referred noise of $\sqrt{4k_B\ 300\ 50}=1.82nV/Hz^{-1/2}$. Now let us check the value using SPICE:
Vin 1 0 DC 1V
Rint 1 2 100
R1 2 0 100
.noise V(2) Vin dec 100 1 200meg
.end
Here the elements are defined between electrical nodes. The voltage source is ideal and the noise analysis is carried out on voltage node 2 with respect to ground (node 0). The independent source is named Vin and the analysis contains 100 points per decade from 1 Hz to 200 MHz. The plot can be seen in Fig. 1 as expected for input and output noise.
Now we add the other components to make a parallel resonant circuit with the resonant frequency 23.2 MHz.
Vin 1 0 DC 1V
Rint 1 2 100
R1 2 0 100
L1 2 0 470nH
C1 2 0 100pF
.noise V(2) Vin dec 100 1 200meg
.end
The plot can be seen in Fig. 2 as expected for input and output noise, where the high frequency tail is due to the effect of the capacitor and the low frequency tail is due to the inductor.
The Q value of a parallel circuit is \begin{equation} Q_p=\omega_0RC=\dfrac{R}{\omega_0L}=R\sqrt{\dfrac{C}{L}} \label{eqn:q} \end{equation} and for this specific circuit we have $Q=1.45$ which is not so large. From the expression in equation \ref{eqn:q} it is obvious that one needs to increase C or R. Let us increase the Q by a factor of 100, by keeping the same resonant frequency. So we multiply the C by a factor of 10 and reduce the L by factor of 10.
Vin 1 0 DC 1V
Rint 1 2 100
R1 2 0 100
L1 2 0 47nH
C1 2 0 1nF
.noise V(2) Vin dec 100 1 200meg
.end
The plot can be seen in Fig. 3 for input and output noise.
It is important to see that this way, the peak output noise has not changed. Of course one can further increase the Q by factor 100 by seeing the effect of the resistance multiplied by this factor.
Vin 1 0 DC 1V
Rint 1 2 100
R1 2 0 10k
L1 2 0 47nH
C1 2 0 1nF
.noise V(2) Vin dec 100 1 200meg
.end
The plot can be seen in Fig. 4 for input and output noise. Note that since the resistor has changed, one expects a lower input referred noise because of $\sqrt{4kT10010000/10100}/(10000/10100)=1.29nV/Hz^{-1/2}$. And since the voltage drop on the 10k resistor is very large, the blue and the red line almost meet.
The loaded circuit
The above circuits were not terminated. Termination is usually due to a load impedance $Z_l$. The loading appears already in the measurement since the input impedance of a real measurement instrument loads the circuit. Of course if the signal is amplified in an amplifier chain, the same situation applies. Let us first consider the termination of the resonant circuit with a resistive load. We expect that both resistances are noisy and contribute to the total input referred noise which can be calculated to be $1.29nV/Hz^{-1/2}$ and a peak output referred noise of $1.27nV/Hz^{-1/2}$. The results can be confirmed in Fig. 5.
Vin 1 0 DC 1V
Rint 1 2 100
R1 2 0 10k
L1 2 0 47nH
C1 2 0 1nF
Rl 2 0 10k
.noise V(2) Vin dec 100 1 200meg
.end
Most RF systems are designed to have an input impedance of 50 ohms, but this might not be the case for all frequencies. For instance, the $S_{11}$ of the low noise amplifier (type BZP102UB1 from B+Z Technologies [6] used for the ESR resonant pickup [7] is depicted in Fig. 6.
$S_{11}$ is a complex quantity and is related to the input impedance of the amplifier as: \begin{equation} Z_{in}=Z_0\left(\dfrac{1+S_{11}}{1-S_{11}}\right) \label{eqn:zin} \end{equation} which makes the input impedance not only complex valued but like the $S_{11}$, also frequency dependent. Here $Z_0$ is a constant which is usually taken to be a real valued transmission line impedance of 50 ohms. The variation of the input impedance with frequency shows that the load is in general reactive. The maximum (noise) power transfer is at frequencies where the input impedance of the load is conjugate matched to that of the source, otherwise reflection of the noise power will results.
We now consider checking the noise of the system at a frequency of e.g. 250 MHz. From the Fig. 6 one can see, that the input resistance of the low noise amplifier at this frequency has a magnitude of about -8.5 dB and a phase of -25 degrees. For a system impedance of 50 Ohms and the frequency of 250 MHz and using equation \ref{eqn:zin} this corresponds to a series load resistor and a capacitance with values of approximately 64.15 Ohms and 81.47 pF respectively. The listing would be:
Vin 1 0 DC 1V
Rint 1 2 100
R1 2 0 10k
L1 2 0 47nH
C1 2 0 1nF
Rl 2 3 64.15
Cl 3 0 81.47pF
.noise V(3) Vin dec 100 1 500meg
.end
The results of the simulation can be shown in Fig. 7. Note that in the simulation now the node number 3 is used for the calculation of available noise power which is the output of the system. One can clearly see the effect of the resonance frequency of the primary resonator at 23 MHz, but also see the non-linear effects of the reactive loading, specially the combination of the reactive loading and the main resonator. It must be mentioned that the curve in Fig. 7 is a result of an equivalent circuit which is calculated for a single point on the curves of Fig. 6. So the most important value on this is the point at the specific frequency of 250MHz one can read an output noise of $124.092pV/Hz^{-1/2}$.
Conclusion
In this work we demonstrated how electrical resonators can be modelled in the SPICE simulation tools.
References
- [1] Homepage of LT-SpiceLINK 🔗
- [2] Homepage of Berkeley SPICE LINK 🔗
- [3] Homepage of NG-SPICELINK 🔗
- [4] Thermal Agitation of Electric Charge in Conductors, H. Nyquist Phys. Rev. 32, 110 (1928) LINK 🔗
- [4] Über spontane Stromschwankungen in verschiedenen Elektrizitätsleitern, W. Schottky, Ann. d. Phys. 362, 23 (1918) LINK 🔗
- [6] B&Z Technologies LINK 🔗
- [7] A fast and sensitive resonant Schottky pick-up for heavy ion storage rings, F. Nolden et. al., Nuclear Instruments and Methods A, v. 659 No. 1 pp. 69–77 (2011). LINK 🔗
- [8] C. Peschke, Private communication 2010.